home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD003b.dsk / DUNKING.MACHINE.bas < prev    next >
BASIC Source File  |  2003-06-12  |  9KB  |  199 lines
  1. 10  REM   THE DUNKING MACHINE<CTRL-J><CTRL-J>
  2. 20 BK = 0:MG = 1:BL = 2:BB = 6:LB = 7:OG = 9:AQ = 14:WH = 15: REM COLORS (MG=MAGENTA,BB=BLUE)
  3. 30  ONERR  GOTO 6000
  4. 40  GOSUB 4000: REM TITLE
  5. 50  GOSUB 5000: REM TONE POKES
  6. 55 ST = 1: GR : GOTO 1350
  7. 1000  REM MAIN LOOP
  8. 1010 X = 10 * RND(1) + PDL(0)/9.11 +2:Y = 22 * RND(1) +(255 - PDL(1))/11.1 +2
  9. 1020 X = X -(X -37) *(X >37)
  10. 1025 Y = Y -(Y -37) *(Y >37)
  11. 1030  IF  INT(10 * RND(1)) = 5  THEN  GOSUB 2020: REM SHIFT EYES
  12. 1040  IF  INT(10 * RND(1)) = 5  THEN  GOSUB 2050: REM TALK
  13. 1050  REM STORE BACKGROUND COLORS
  14. 1060 C(1) =  SCRN( X -2,Y):C(2) =  SCRN( X -1,Y):C(3) =  SCRN( X +1,Y):C(4) =  SCRN( X +2,Y):C(5) =  SCRN( X,Y +2):C(6) =  SCRN( X,Y +1):C(7) =  SCRN( X,Y -1):C(8) =  SCRN( X,Y -2)
  15. 1070  COLOR= 1
  16. 1080  REM DRAW SIGHT
  17. 1090  HLIN X -2,X -1 AT Y: HLIN X +1,X +2 AT Y: VLIN Y -1,Y -2 AT X: VLIN Y +1,Y +2 AT X
  18. 1100  POKE 768,(X +Y) *3: POKE 769,4: CALL 770
  19. 1110  REM BUTTON?
  20. 1120  FOR TI = 0 TO 5
  21. 1130  IF  PEEK( -16286) >127  OR  PEEK( -16287) >127  THEN 1190
  22. 1140  NEXT 
  23. 1150  REM REDRAW BACKGROUND
  24. 1160  COLOR= C(1): PLOT X -2,Y: COLOR= C(2): PLOT X -1,Y: COLOR= C(3): PLOT X +1,Y: COLOR= C(4): PLOT X +2,Y: COLOR= C(5): PLOT X,Y +2: COLOR= C(6): PLOT X,Y +1
  25. 1170  COLOR= C(7): PLOT X,Y -1: COLOR= C(8): PLOT X,Y -2
  26. 1180  GOTO 1010
  27. 1190  POKE 768,5: FOR TI = 1 TO 5: POKE 769,4: CALL 770: NEXT 
  28. 1200 TRY = TRY +1
  29. 1210  IF  SCRN( X,Y) = 9  THEN 1260
  30. 1220  POKE 768,255: FOR TI = 1 TO 50: POKE 769,3: CALL 770: NEXT 
  31. 1230  IF TRY = 3  THEN TRY = 0: GOSUB 2090: GOTO 1350
  32. 1240  GOTO 1160
  33. 1250  REM DUNK HIM!
  34. 1260 DUNK = 1
  35. 1270  FOR TI = 0 TO 3
  36. 1280  FOR T = 255 TO 75  STEP  -10: POKE 768,T: POKE 769,8: CALL 770: NEXT 
  37. 1290  NEXT TI
  38. 1300  RESTORE 
  39. 1310  FOR TI = 0 TO 5: READ X,Y: POKE 768,X: POKE 769,Y: CALL 770: NEXT 
  40. 1320  GOSUB 2240
  41. 1330  POKE 768,200: FOR TI = 1 TO 15: POKE 769,40: CALL 770: NEXT 
  42. 1340 PLSC = PLSC +1:TRY = 0
  43. 1350  HOME : IF ST  THEN 1370
  44. 1370  INVERSE : PRINT "             CURRENT SCORE:             ";: NORMAL 
  45. 1380  IF VS >PL  THEN  FLASH 
  46. 1390  HTAB 14: PRINT "JACK NIFE... "VSC
  47. 1400  IF PLSC <VSC  THEN  NORMAL 
  48. 1410  IF PL >VS  THEN  FLASH 
  49. 1420  HTAB 14: PRINT "PLAYER...... "PLSC
  50. 1425  IF ST  THEN ST = 0: INVERSE : POKE 2039,32: GOTO 1460
  51. 1430  INVERSE : PRINT "    PRESS PADDLE BUTTON TO TRY AGAIN   ";: POKE 2039,32
  52. 1440  IF  PEEK( -16286) >127  OR  PEEK( -16287) >127  THEN 1460
  53. 1450  GOTO 1440
  54. 1460  VTAB 24: HTAB 1: PRINT  SPC( 39);:DUNK = 0: GOSUB 3020
  55. 1470  GOTO 1000
  56. 2000  REM ANIMATION
  57. 2010  REM SHIFT EYES
  58. 2020  COLOR= 11: IF  SCRN( 12,6) = 2  THEN  PLOT 12,6: PLOT 14,6: COLOR= 2: PLOT 11,6: PLOT 13,6: RETURN 
  59. 2030  PLOT 11,6: PLOT 13,6: COLOR= 2: PLOT 12,6: PLOT 14,6: RETURN 
  60. 2040  REM CHATTER
  61. 2050  IF  SCRN( 12,9) = 1  THEN  COLOR= 11: HLIN 12,13 AT 9: RETURN 
  62. 2060  FOR TI = 1 TO 8 * RND(1) +5
  63. 2070  COLOR= 1: HLIN 12,13 AT 9: POKE 768,150 + INT(100 * RND(1)): POKE 769, INT(3 * RND(1)) +1: CALL 770: COLOR= 11: HLIN 12,13 AT 9
  64. 2080  NEXT : RETURN 
  65. 2090  REM RAISE ARMS
  66. 2095  COLOR= C(1): PLOT X -2,Y: COLOR= C(2): PLOT X -1,Y: COLOR= C(3): PLOT X +1,Y: COLOR= C(4): PLOT X +2,Y: COLOR= C(5): PLOT X,Y +2: COLOR= C(6): PLOT X,Y +1
  67. 2096  COLOR= C(7): PLOT X,Y -1: COLOR= C(8): PLOT X,Y -2
  68. 2100  COLOR= 4: HLIN 6,15 AT 15
  69. 2110  COLOR= 7: VLIN 12,14 AT 16: HLIN 7,9 AT 14: HLIN 8,9 AT 13: PLOT 9,12
  70. 2120  COLOR= 12: VLIN 10,11 AT 10: VLIN 10,11 AT 15: VLIN 8,11 AT 9: VLIN 7,10 AT 8: VLIN 7,8 AT 7
  71. 2130  VLIN 8,11 AT 16: VLIN 7,10 AT 17: VLIN 7,8 AT 18
  72. 2140  COLOR= 11: HLIN 7,8 AT 6: PLOT 8,5: PLOT 17,5
  73. 2150  FOR T = 1 TO 6
  74. 2160  COLOR= 11: HLIN 17,18 AT 6
  75. 2170  COLOR= 1: HLIN 12,13 AT 9
  76. 2180  IF DUNK  THEN  RETURN 
  77. 2190  POKE 768,0: FOR TI = 1 TO 20: POKE 769,2: CALL 770: NEXT 
  78. 2200  COLOR= 11: HLIN 12,13 AT 9
  79. 2210  FOR TI = 1 TO 50: NEXT : NEXT 
  80. 2220 VSC = VSC +1: RETURN 
  81. 2230  REM DUNKING ANIMATION
  82. 2240  GOSUB 2100
  83. 2250  COLOR= LB: VLIN 17,27 AT 36: COLOR= BK: VLIN 16,27 AT 35
  84. 2260  COLOR= WH: VLIN 18,26 AT 34: COLOR= OG: VLIN 19,25 AT 33
  85. 2270  COLOR= LB: VLIN 16,27 AT 35
  86. 2280  PLOT 34,27: PLOT 28,17: PLOT 22,22
  87. 2290  COLOR= BK: VLIN 15,26 AT 34
  88. 2300  PLOT 33,16: PLOT 28,28: PLOT 22,23
  89. 2310  COLOR= WH: VLIN 19,25 AT 33
  90. 2320  PLOT 29,27: PLOT 33,17
  91. 2330  PLOT 30,19: COLOR= OG: PLOT 30,26
  92. 2340  COLOR= BK: PLOT 28,29: PLOT 29,28
  93. 2350  PLOT 29,18
  94. 2360  COLOR= LB: PLOT 28,18: PLOT 29,17
  95. 2370  PLOT 22,23: PLOT 23,22
  96. 2380  COLOR= 4: PLOT 24,22
  97. 2390  COLOR= BK: PLOT 22,25: PLOT 23,24: PLOT 24,23
  98. 2400  COLOR= WH: PLOT 30,26
  99. 2410  COLOR= OG: VLIN 19,24 AT 32
  100. 2420  COLOR= BK: PLOT 27,21: COLOR= LB: PLOT 27,22
  101. 2430  COLOR= WH: PLOT 32,25
  102. 2440  REM 
  103. 2450  COLOR= LB: PLOT 3,23: COLOR= MG: PLOT 21,23
  104. 2460  COLOR= LB: PLOT 4,22: COLOR= MG: PLOT 22,22
  105. 2470  COLOR= LB: PLOT 5,21: COLOR= MG: PLOT 23,21
  106. 2480  COLOR= MG: HLIN 4,8 AT 24
  107. 2490  PLOT 11,24: HLIN 14,18 AT 24
  108. 2500  HLIN 20,21 AT 24
  109. 2510  COLOR= LB: VLIN 23,24 AT 4: COLOR= MG: VLIN 23,24 AT 22
  110. 2520  COLOR= LB: VLIN 22,24 AT 5: COLOR= MG: VLIN 22,23 AT 23
  111. 2530  COLOR= MG: HLIN 6,8 AT 25
  112. 2540  PLOT 11,25: HLIN 14,18 AT 25: HLIN 20,21 AT 25
  113. 2550  REM 
  114. 2560  COLOR= MG: VLIN 21,25 AT 9: COLOR= AQ: VLIN 26,27 AT 9
  115. 2570  COLOR= BB: VLIN 21,27 AT 11
  116. 2580  COLOR= BL: VLIN 21,27 AT 12
  117. 2590  COLOR= MG: VLIN 20,27 AT 13
  118. 2600  COLOR= BB: VLIN 21,27 AT 14: VLIN 20,27 AT 15
  119. 2610  REM 
  120. 2620  COLOR= LB: FOR Y = 4 TO 9: HLIN 6,20 AT Y: NEXT : COLOR= 4: HLIN 6,20 AT 10
  121. 2630  COLOR= LB: FOR Y = 11 TO 14: HLIN 7,19 AT Y: NEXT 
  122. 2640  FOR Y = 16 TO 19: HLIN 7,18 AT Y: NEXT 
  123. 2650  COLOR= MG: FOR Y = 20 TO 25: HLIN 10,15 AT Y: NEXT 
  124. 2660  COLOR= AQ: FOR Y = 26 TO 28: HLIN 10,15 AT Y: NEXT 
  125. 2670  FOR T = 0 TO 49: COLOR= AQ
  126. 2680  VLIN 28,5 * RND(1) AT 22 * RND(1) +2
  127. 2690 TI =  PEEK( -16336)
  128. 2700  COLOR= 4: HLIN 2,18 AT 15: PLOT 20,14: PLOT 21,13: PLOT 22,12: PLOT 23,11: VLIN 15,28 AT 19
  129. 2710  NEXT : RETURN 
  130. 3000  REM SET UP GRAPHICS
  131. 3010  GR 
  132. 3020  COLOR= 7: FOR Y = 0 TO 33: HLIN 0,39 AT Y: NEXT : COLOR= 8: FOR Y = 34 TO 39: HLIN 0,39 AT Y: NEXT : COLOR= 4: VLIN 15,39 AT 1: VLIN 15,39 AT 19: HLIN 2,18 AT 15: HLIN 2,18 AT 39
  133. 3021  PLOT 2,14: PLOT 3,13: PLOT 4,12: PLOT 5,11: PLOT 6,10
  134. 3030  VLIN 10,24 AT 6: PLOT 20,14: PLOT 21,13: PLOT 22,12: PLOT 23,11: PLOT 24,10
  135. 3040  HLIN 7,23 AT 10: VLIN 11,34 AT 24
  136. 3050  COLOR= 14: FOR Y = 29 TO 38: HLIN 2,18 AT Y: NEXT 
  137. 3060  HLIN 3,18 AT 28: HLIN 4,18 AT 27: HLIN 5,18 AT 26: HLIN 6,18 AT 25
  138. 3070  FOR Y = 25 TO 34: HLIN 20,23 AT Y: NEXT 
  139. 3080  HLIN 20,22 AT 35: HLIN 20,21 AT 36: PLOT 20,37
  140. 3085  COLOR= 4: PLOT 20,38: PLOT 21,37: PLOT 22,36: PLOT 23,35
  141. 3090  COLOR= 1: HLIN 6,18 AT 20: HLIN 20,23 AT 20: HLIN 5,18 AT 21: HLIN 20,22 AT 21: HLIN 4,18 AT 22: HLIN 20,21 AT 22: HLIN 3,18 AT 23: PLOT 20,23
  142. 3100  COLOR= 0: HLIN 22,27 AT 22: VLIN 18,26 AT 28: VLIN 18,26 AT 36: HLIN 28,36 AT 17: HLIN 28,36 AT 27
  143. 3110  COLOR= 15: FOR Y = 18 TO 26: HLIN 29,35 AT Y: NEXT 
  144. 3120  COLOR= 9: FOR Y = 19 TO 25: HLIN 30,34 AT Y: NEXT 
  145. 3150  REM DRAW JACK
  146. 3160  COLOR= 6: VLIN 21,27 AT 9: HLIN 10,15 AT 19
  147. 3170  VLIN 21,27 AT 10: HLIN 11,14 AT 5: HLIN 12,13 AT 4
  148. 3180  VLIN 21,27 AT 12: VLIN 21,27 AT 13
  149. 3190  HLIN 10,11 AT 20: HLIN 13,14 AT 20
  150. 3200  COLOR= 2: VLIN 21,22 AT 11
  151. 3210  VLIN 21,22 AT 14: PLOT 12,20: VLIN 20,22 AT 15
  152. 3220  COLOR= 12: FOR Y = 16 TO 18: HLIN 10,15 AT Y: NEXT 
  153. 3230  FOR Y = 12 TO 14: HLIN 10,15 AT Y: NEXT 
  154. 3240  HLIN 11,14 AT 11: VLIN 12,14 AT 9: VLIN 13,14 AT 8: PLOT 7,14: VLIN 12,14 AT 16
  155. 3250  COLOR= 11: HLIN 12,13 AT 10: PLOT 10,6: PLOT 15,6
  156. 3260  FOR Y = 6 TO 9: HLIN 11,14 AT Y: NEXT : HLIN 6,7 AT 15: HLIN 12,13 AT 15
  157. 3270  COLOR= 2: PLOT 12,6: PLOT 14,6: COLOR= 8: HLIN 11,14 AT 8
  158. 3280  RETURN 
  159. 4000  REM INSTRUCTIONS
  160. 4010  TEXT : HOME : VTAB 5
  161. 4020  HTAB 11: FLASH : PRINT " THE DUNKING MACHINE "
  162. 4030  NORMAL : PRINT 
  163. 4040  HTAB 16: PRINT "BY JIM GANZ"
  164. 4050  PRINT : PRINT 
  165. 4060  PRINT : PRINT "USE PADDLES 1 AND 2 TO CONTROL SIGHT,": PRINT 
  166. 4070  PRINT "PRESS EITHER BUTTON TO FIRE. YOU HAVE 3": PRINT 
  167. 4080  PRINT "TRIES BEFORE YOU LOSE. <<<GOOD LUCK!>>>"
  168. 4090  VTAB 20: INPUT "PRESS 'RETURN' TO BEGIN";A$
  169. 4100  RETURN 
  170. 5000  REM POKE TONE ROUTINE
  171. 5010  FOR T = 1 TO 12: READ TI: NEXT : FOR T = 770 TO 790: READ TI: POKE T,TI: NEXT 
  172. 5020  RETURN 
  173. 5030  REM TONE & MUSIC DATA
  174. 5040  DATA 170,80,170,70,200,80,150,80,170,100,200,120,173,48,192,136,208,5,206,1,3,240,9,202,208,245,174,0,3,76,2,3,96
  175. 6000  NORMAL : TEXT : HOME : TEXT : END 
  176. 7000  REM 
  177. 7010  REM 
  178. 7020  REM  "THE DUNKING MACHINE"
  179. 7030  REM 
  180. 7040  REM        A LOW-RES
  181. 7050  REM      ANIMATED GAME
  182. 7060  REM     FOR  ONE PLAYER
  183. 7070  REM 
  184. 7080  REM       BY JIM GANZ
  185. 7090  REM 
  186. 7100  REM        FEB, 1981
  187. 7110  REM 
  188. 7120  REM  REQUIREMENTS:
  189. 7130  REM  APPLESOFT ][ AND
  190. 7140  REM  GAME PADDLES
  191. 7150  REM 
  192. 7160  REM        CLASSIFIED
  193. 7170  REM     -PUBLIC  DOMAIN-
  194. 7180  REM      NOVEMBER, 1981
  195. 7190  REM 
  196. 7200  REM PLEASE RETAIN LINES
  197. 7210  REM 7000-7230
  198. 7220  REM IN ALL COPIES.
  199. 7230  REM        -THANK YOU!!